Screener Ichimoku, trouver des actions en tendance

Dans cet article je vais vous donner le code prorealtime d’un screener Ichimoku permettant de trouver les actions qui sont en tendance haussière, mais aussi en tendance baissière.

En trading la tendance est ton amie. Et l’indicateur Ichimoku est un des plus simples indicateurs d’analyse technique pour visualiser une tendance. « Ichimoku Kinko Hyo » voulant dire  « Voir l’équilibre de la courbe en un coup d’oeil ». La position des prix par rapport au Kumo (Nuage) et l’orientation de celui-ci indiquant clairement l’orientation du marché.

Je ne reviendrais pas sur la signification des lignes de l’Ichimoku. Vous pouvez en retrouver la définition sur Wikipedia. A la fin de l’article retrouvez la vidéo expliquant commant utiliser le screener.

La tendance en trading

La majorité des stratégies en trading sont basées sur le principe de toujours de prendre position dans le sens de la tendance. C’est d’ailleurs une des erreurs fréquentes du débutant d’acheter des actions qui baissent ou de vendre des actions qui montent.

Il y a des stratégies de contre tendance, quand une action est sur achetée ou sur vendue, mais ce sont des stratégies de courtes durées. Visant à prendre position sur une courte période pour profiter d’un retracement dans une phase haussière, ou d’un rallye haussier dans une phase baissière. Et même là le trader aura au préalable identifié la tendance principale de l’action.

Tendance haussière avec Ichimoku

Le trend d’une action sera jugé haussier avec l’indicateur Ichimoku si les conditions suivantes sont réunies :

1. Les cours sont au-dessus du nuage
2. La Tenkan et la Kijun sont au-dessus du nuage
3. Le Kumo projeté dans le futur est haussier et avec une pente ascendante
4. Les cours sont au-dessus de la Tenkan et la Tenkan au-dessus de la Kijun 

Le quatrième point peut ne pas être respecté dans une période de retracement sans remettre en cause la tendance générale.

La tendance haussière sera confirmée par la Chikou qui devra être au-dessus des prix et n’avoir aucun obstacle.

Exemple de tendance haussière, le titre Danone en 2019

Tendance à la baisse avec Ichimoku

Pour un titre baissier les rêgles seront inversées :

1. Les cours sont sous du nuage
2. La Tenkan et la Kijun sont en-dessous du nuage
3. Le Kumo projeté dans le futur est baissier et avec une pente descendante
4. Les cours sont en-dessous de la Tenkan et la Tenkan sous de la Kijun

La tendance baissière sera elle confirmée par la Chikou qui devra être sous des prix et n’avoir aucun obstacle.

Exemple de tendance baissière, le titre Renault depuis la fin 2019

Le screener Ichimoku

Un screener un petit programme qui avec rechercher des actions qui correspondent à des critères pré-définis. La plateforme que j’utilise, est celle de ProRealtime. C’est un logiciel gratuit qui vous permet d’analyser les actions, devises, indices, crypto-monnaie … Leur outils de screener est très puissant et simple d’utilisation.

J’ai réalisé 2 screeners, un pour les titres en tendance haussière et un deuxième pour ceux en tendance baissière. Vous pouvez soit recopier le code pour l’écrire dans ProRealtime, soit télécharger le fichier correspondant pour l’importer.

Vous pourrez les adapter en ajoutant ou modifiant les critères de sélection selon votre style de trading.

Screener Ichimoku à la hausse

Le screener retourne les valeurs qui sont à la hausse depuis au moins 26 périodes, il est possible de modifier en changeant la valeur de la variable NbJoursTendance au début du script.

Il calcule à la fin depuis combien temps la valeur est à la hausse pour pouvoir afficher les plus récentes en premier gâce à la variable « Trend ». Une valeur restant à la hausse plusieurs jours sera retourner tous les jours par le screener.

//Ichimoku Tendance Hausse www.swingtrading.pro

once NbJoursTendance = 26
once shift = 25

Tenkan = (highest[9](high)+lowest[9](low))/2
Kijun = (highest[26](high)+lowest[26](low))/2

//Kumo futur
SSpanAf = (tenkan+kijun)/2
SSpanBf = (highest[52](high)+lowest[52](low))/2

// Kumo
SSpanA = SSpanAF[Shift]
SSpanB = SSpanBF[Shift]

// Condition de hausse
 Hausse = Tenkan > SSpanA and Kijun > SSpanA and SSpanA > SSpanB and SSpanAf > SSpanBf and close > SSpanA
 //Confirmation avec la Chikou
 ChikouConfirme = close > SSpanA[26] and close > SSpanB[26] and close > close[26]
 //Condition haussière depuis au minimum NbJoursTendance
 TendanceH = summation[NbJoursTendance](Hausse) = NbJoursTendance 

//Calcul du nombre de jour depuis que la tendance est établie pour trier l'affichage
 IF TendanceH and IsLastBarUpdate THEN
 I = 0
 Haussier = 1
 WHILE I < 150 and Haussier = 1 do
 IF not Hausse[I] then
 Haussier = 0
 endif
 I = I + 1
 wend

Trend = I - 1

ENDIF

SCREENER[TendanceH and ChikouConfirme] ( Trend as "NbJoursHausse")

Screener Ichimoku à la baisse

Le screener des valeurs baissières fonctionne sur le même principe que celui à la hausse.

//Ichimoku Tendance Baisse www.swingtrading.pro
once NbJoursTendance = 26
once shift = 25

Tenkan = (highest[9](high)+lowest[9](low))/2
Kijun = (highest[26](high)+lowest[26](low))/2

//Kumo futur
SSpanAf = (tenkan+kijun)/2
SSpanBf = (highest[52](high)+lowest[52](low))/2

// Kumo
SSpanA = SSpanAF[Shift]
SSpanB = SSpanBF[Shift]

// Condition de baisse
Baisse = Tenkan < SSpanA AND Kijun < SSpanA and SSpanA < SSpanB and SSpanAf < SSpanBf and close < SSpanA
//Confirmation avec la Chikou
ChikouConfirme = close < SSpanA[26] and close < SSpanB[26] and close < close[26]
//Condition depuis au minimum NbJoursTendance
TendanceB = summation[NbJoursTendance](Baisse) = NbJoursTendance

//Calcul du nombre de jour depuis que la tendance est établie pour trier l'affichage
IF TendanceB and IsLastBarUpdate THEN
I = 0
Baissier = 1
WHILE I < 150 and Baissier = 1 do
IF not Baisse[I] then
Baissier = 0
endif
I = I + 1
wend

Trend = I - 1

ENDIF

SCREENER[TendanceB and ChikouConfirme] ( Trend as "NbJoursBaisse")

J’espère que ces screeners vous aiderons dans votre trading. N’hésitez pas à les adapter à votre style de trading en ajoutant ou supprimant des critères de sélections.

Vos commentaires et remarques sont les bienvenues.

Bon Trades

Georges